***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 27, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C12 A K 
.param
+vc0 = 3.146e-11	 vc1 = 7.916e-12		 vc2 = 2.463e-11		vc3 = 1.605e-1
+tc1 = 2.451e-2		 tc2 = 1.321e-2
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A)+vc2*exp(vc3*v(K,A)))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 5.265e-15	   n = 1.085		  rs = 6.051e-1
+ibv = 5e-3		 nbv = 1.0		  bv = 12
+ikf = 1e-2
***** capacitance parameter *****
+cjo = 3.593e-11	   m = 3.312e-1		  vj = 5.811e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.148		 xti = 3
+trs1 = -3.825e-4	tbv1 = 6.487e-4		tikf = 1e-2
.ends BZT52-C12
*$
